: say ( s -- )
	me @ swap notify
;
: main ( s -- )
	dup not if
		pop "Usage: @last <player>" say
		exit
	then
	.pmatch+ dup not if
		pop "@Last: Player not found." say
		exit
	then
	"@Last information for " over name strcat ":" strcat say
	"-----------------------" "----------------" 3 pick
	name strlen strcut pop strcat say
	"Most recent connect:     " over "*connect" getpropstr
	atoi ctime strcat say
	"Most recent disconnect:  " over "*disconnect" getpropstr
	atoi ctime strcat say
	"Duration of connection:  "
	over awake? 3 pick "D" flag? not and if
		over "*connect" getpropstr atoi
		systime swap - .timefmt
	else
		over "*connect" getpropstr atoi 3 pick
		"*disconnect" getpropstr atoi > if
			"Duration unavailable"
		else
			over "*disconnect" getpropstr atoi
			3 pick "*connect" getpropstr atoi -
			.timefmt
		then
	then
	strcat say
	"Offline elapsed time:    "
	over awake? 3 pick "D" flag? not and if
		"Player is currently online"
	else
		over "*connect" getpropstr atoi
		3 pick "*disconnect" getpropstr atoi > not if
			over "*disconnect" getpropstr atoi
			systime swap - .timefmt
		else
			"Elapsed time unavailable"
		then
	then
	strcat say
	pop
;