: get_title
	dup not if
		pop me @ "Title of the work?" notify
		read then
	me @ "Title:  " 3 pick strcat notify
	me @ "Is this correct (y/n)?" notify
	read "n" stringcmp not if
		pop "" get_title then
;
: main
	trigger @ me @ intostr "_" swap strcat getpropstr
		dup not if
			pop
		else
			atoi dbref dup ok? if
				dup "*tome" prop-exists? if
					.fmatch swap pop
					"You already have a book:  "
					swap strcat me @ swap notify exit
				then
			then
			pop me @ intostr "_" swap strcat
			trigger @ swap remove_prop
		then
	me @ pennies 50 < if
		pop me @ "Books cost $50." notify exit then
	me @ -50 addpennies
	get_title
	1 create
	trigger @ me @ intostr "_" swap strcat
	3 pick intostr 0 addprop
	"Book \"" over .fmatch strcat
	"\" created." strcat me @ swap notify
	dup "*tome" "yes" 0 addprop
	trigger @ "*book_prog" getpropstr atoi dbref
	over "book help" swap open dup prog owner chown over addlink
	over "inscribe" swap open dup prog owner chown over addlink
	over "delete" swap open dup prog owner chown over addlink
	over "view" swap open dup prog owner chown over addlink
	over "contents" swap open dup prog owner chown over addlink
	pop dup trigger @ location "_library" getpropstr
	atoi dbref addlink dup "S" set
	me @ "Actions attached.  Use 'book help' for help." notify
	me @ "Thank you for buying a tome." notify
	"This book was authored by " over owner name strcat "." strcat
	"  For information on how to use this book, simply type 'book "
	"help'.  If you would like to return this book to the library ("
	"which is strongly recommended) simply drop it anywhere."
	strcat strcat strcat setdesc
;